بنهاية الوحدة، يُتوقع القدرة على:

• تحديد ما إذا كان المكوّن Input أو Output.
• تحديد ما إذا كانت الإشارة Digital أو Analog.
• اختيار الدالة المناسبة للتعامل مع المكوّن.
• قراءة قيم مجموعة من الحساسات.
• التحكم في مجموعة من وحدات الإخراج.
• إضافة مكتبة برمجية إلى بيئة تطوير أردوينو.
• استدعاء مكتبة داخل البرنامج.
• استخدام الأمثلة الجاهزة للمكتبات.
• استخدام مكونات تحتاج إلى مكتبات برمجية.

تعلمنا في الوحدة السابقة أربع عمليات أساسية:

في هذه الوحدة سنستخدم هذه العمليات مع مكونات مختلفة.

قبل كتابة الكود، اسأل:

التوصيل:

يوصل أحد طرفي Tilt Switch بالمنفذ D2 والطرف الآخر بـ GND.

الكود:

const int tiltPin = 2;

void setup()
{
    pinMode(tiltPin, INPUT_PULLUP);
    Serial.begin(9600);
}

void loop()
{
    int state = digitalRead(tiltPin);

    Serial.println(state);

    delay(200);
}

غيّر اتجاه الحساس ولاحظ تغير القراءة في Serial Monitor.

التوصيل:

الكود:

const int pirPin = 2;

void setup()
{
    pinMode(pirPin, INPUT);
    pinMode(LED_BUILTIN, OUTPUT);
}

void loop()
{
    int motion = digitalRead(pirPin);

    if (motion == HIGH)
    {
        digitalWrite(LED_BUILTIN, HIGH);
    }
    else
    {
        digitalWrite(LED_BUILTIN, LOW);
    }
}

عند اكتشاف حركة تعمل اللمبة المدمجة في لوحة أردوينو.

التوصيل:

يقرأ A0 الجهد المتغير عند نقطة التقاء Photoresistor مع المقاومة.

الكود:

const int lightPin = A0;

void setup()
{
    Serial.begin(9600);
}

void loop()
{
    int lightValue = analogRead(lightPin);

    Serial.println(lightValue);

    delay(200);
}

جرّب:

• تغطية Photoresistor.
• تعريضه لضوء أقوى.

ثم راقب تغير القراءة.

التوصيل:

الكود:

const int waterPin = A0;

void setup()
{
    Serial.begin(9600);
}

void loop()
{
    int waterValue = analogRead(waterPin);

    Serial.println(waterValue);

    delay(200);
}

راقب تغير القراءة عند تغير مقدار ملامسة الماء للحساس.

يمكننا باستخدام Passive Buzzer تحديد تردد الصوت.

نستخدم:

tone();

ولإيقاف الصوت:

noTone();

ولا نحتاج إلى مكتبة برمجية خارجية.

في هذا المثال نستخدم Piezo ذا طرفين.

التوصيل:

سنكتب ترددات النغمات مباشرة داخل البرنامج.

const int buzzerPin = 8;

int melody[] = {
    523, 587, 659, 698,
    784, 880, 988, 1047
};

void setup()
{
}

void loop()
{
    for (int i = 0; i < 8; i++)
    {
        tone(buzzerPin, melody[i], 500);
        delay(700);
    }

    noTone(buzzerPin);

    delay(2000);
}

القيم مثل:

523
587
659

تمثل ترددات صوتية بوحدة Hertz.

يرسل أردوينو نبضة قصيرة إلى:

Trig

ثم يرسل الحساس موجة صوتية.

عندما ترتد الموجة من جسم، تظهر نبضة على:

Echo

نقيس زمن عودة الموجة:

التوصيل:

Trig = Digital Output، وEcho = Digital Input.

الكود:

const int trigPin = 9;
const int echoPin = 10;

void setup()
{
    pinMode(trigPin, OUTPUT);
    pinMode(echoPin, INPUT);

    Serial.begin(9600);
}

void loop()
{
    digitalWrite(trigPin, LOW);
    delayMicroseconds(2);

    digitalWrite(trigPin, HIGH);
    delayMicroseconds(10);

    digitalWrite(trigPin, LOW);

    long duration = pulseIn(echoPin, HIGH);

    float distance = duration * 0.0343 / 2;

    Serial.println(distance);

    delay(200);
}

لإرسال النبضة:

digitalWrite();

لإنشاء تأخير صغير جدًا:

delayMicroseconds();

لقياس مدة نبضة Echo:

pulseIn();

ثم حسبنا المسافة بأنفسنا:

float distance = duration * 0.0343 / 2;

سنعود لاحقًا إلى الحساس نفسه بعد تعلم استخدام المكتبات البرمجية.

تعرفنا سابقًا على مفهوم المكتبة البرمجية.

في هذه الوحدة سنتعلم كيفية:

المكتبة تساعدنا على التعامل مع المكونات التي تحتاج إلى خطوات برمجية أكثر تعقيدًا.

نستدعي المكتبة باستخدام:

#include <LibraryName.h>

مثال:

#include <Servo.h>

تكتب #include في بداية البرنامج، قبل:

void setup()

بعد ذلك يمكننا استخدام الدوال والأدوات التي توفرها المكتبة.

تعاملنا سابقًا مع HC-SR04 بدون مكتبة.

كان علينا تنفيذ:

يمكن استخدام مكتبة جاهزة لتنفيذ جزء كبير من هذه التفاصيل.

من المكتبات المستخدمة لهذا الغرض:

NewPing

التوصيل:

Trig = Digital Output، وEcho = Digital Input.

نستدعي المكتبة:

#include <NewPing.h>

ثم:

const int trigPin = 9;
const int echoPin = 10;
const int maxDistance = 200;

NewPing sonar(trigPin, echoPin, maxDistance);

لقراءة المسافة:

int distance = sonar.ping_cm();

فتعطينا المكتبة المسافة بالسنتيمتر مباشرة.

التوصيل:

Trig = Digital Output، وEcho = Digital Input.

#include <NewPing.h>

const int trigPin = 9;
const int echoPin = 10;
const int maxDistance = 200;

NewPing sonar(trigPin, echoPin, maxDistance);

void setup()
{
    Serial.begin(9600);
}

void loop()
{
    int distance = sonar.ping_cm();

    Serial.println(distance);

    delay(200);
}

قارن هذا الكود بالمثال الذي كتبناه سابقًا بدون مكتبة.

بدون مكتبة

نحن مسؤولون عن:

Trig
Echo
قياس الزمن
حساب المسافة

باستخدام المكتبة

يمكن أن نكتب:

sonar.ping_cm();

وتعيد لنا المسافة مباشرة.

المكتبة لا تغير طريقة عمل الحساس.

إنما تجعل التعامل البرمجي معه أسهل.

يستخدم المثال Servo صغيرًا بدون حمل.

التوصيل:

الكود:

#include <Servo.h>

Servo myServo;

void setup()
{
    myServo.attach(9);
}

void loop()
{
    myServo.write(0);
    delay(1000);

    myServo.write(90);
    delay(1000);

    myServo.write(180);
    delay(1000);
}

إنشاء Servo باسم:

Servo myServo;

ربطه بمنفذ أردوينو:

myServo.attach(9);

تحريكه إلى زاوية:

myServo.write(90);

بفضل المكتبة أصبح التحكم في Servo باستخدام أوامر بسيطة.

نستدعي المكتبة:

#include <Keypad.h>

ثم نحدد عدد الصفوف والأعمدة:

const byte rows = 4;
const byte cols = 4;

ونحدد شكل الأزرار:

char keys[rows][cols] =
{
    {'1','2','3','A'},
    {'4','5','6','B'},
    {'7','8','9','C'},
    {'*','0','#','D'}
};

التوصيل:

ترتيب أطراف الصفوف والأعمدة قد يختلف حسب نوع الـKeypad المستخدم.

الكود الكامل:

#include <Keypad.h>

const byte rows = 4;
const byte cols = 4;

char keys[rows][cols] =
{
    {'1','2','3','A'},
    {'4','5','6','B'},
    {'7','8','9','C'},
    {'*','0','#','D'}
};

byte rowPins[rows] = {9, 8, 7, 6};
byte colPins[cols] = {5, 4, 3, 2};

Keypad keypad = Keypad(
    makeKeymap(keys),
    rowPins,
    colPins,
    rows,
    cols
);

void setup()
{
    Serial.begin(9600);
}

void loop()
{
    char key = keypad.getKey();

    if (key)
    {
        Serial.println(key);
    }
}

عند الحصول على مكوّن جديد:

تعاملنا مع مكونات بدون مكتبات برمجية:

• Tilt Ball Switch.
• PIR Motion Sensor.
• Photoresistor.
• Water Level Sensor.
• Passive Buzzer.
• Ultrasonic Sensor.

ثم تعلمنا:

• استدعاء مكتبة باستخدام #include.
• تثبيت المكتبات من Library Manager.
• استخدام الأمثلة الجاهزة.

وتعاملنا باستخدام المكتبات مع:

• Ultrasonic Sensor.
• Servo Motor.
• Membrane Keypad.

الهدف الأساسي من الوحدة:

فهم نوع الإشارة واختيار المنفذ والدالة المناسبة، ثم معرفة متى وكيف نستخدم مكتبة برمجية.